Vista - what does the '48' mean?

Found a script that tries to determine whether a PC is a desktop or laptop.
One of the lines of code is:
Set colItems = objWMIService.ExecQuery( "Select * from Win32_Battery", , 48 )
Does anyone know what the 48 refers to?
Thanks.

48 brings up a yellow box with an Exclamation mark in it.


"Tony Logan" <TonyLogan@xxxxxx> wrote in message
news:4B1DD4D9-325C-4CE0-9FC3-938A94D51271@xxxxxx

"Tony Logan" wrote:

48 = wbemFlagForwardOnly (32) + wbemFlagReturnImmediately (16), which means
that you can enumerate colItems only once and you can't use colItems.Count.
Also, if there is an error, it is not reported untill you try to access
colItems.

--
urkec

"urkec" <urkec@xxxxxx> wrote in message
news:9DB1C913-DBCD-4384-ABEB-420C3DDF9242@xxxxxxI see that TypeName(colItems) returns SWbemObjectSet whether the collection
contains any items or not. I'm hoping you or someone has a way to find out
if the collection has any items without resorting to handling the error that
occurs when you try to access it.

Also, is it necessary to use the two flags in the 48? Can other, more
friendly flags be used? If so, what might they be?

Thanks in advance,
-Paul Randall

"Paul Randall" <paulr90@xxxxxx> wrote in message
news:OchrrR09IHA.4456@xxxxxxI don't know, but this is certainly a good illustration of the value of
making good use of constants as a way to make the intent of one's code
clearer.

/Al

Paul Randall schrieb:A list of flags to use with .ExecQuery can be found here

http://msdn.microsoft.com/en-us/libr...70(VS.85).aspx

or here:

http://msdn.microsoft.com/en-us/libr...07(VS.85).aspx

For (some of) the numerical values see

http://msdn.microsoft.com/en-us/library/cc215511.aspx
http://msdn.microsoft.com/en-us/library/cc215515.aspx

To make sure and to get a complete list, look into the pertinent header
file (provider.h (?)).

Whether all flags work as expected with your version of OS, WSH, VBScript,
and WMI remains to be seen.

"Paul Randall" wrote:
The default is wbemFlagReturnImmediately (16), and if you don't use any
other flags, you can use colItems.Count (even if the collection is empty) and
enumerate it more than once:


Set colItems = objWMIService.ExecQuery _
("Select * from Win32_Battery")

WScript.Echo TypeName(colItems)
WScript.Echo colItems.Count

For Each objItem In colItems
WScript.Echo objItem.Name
Next


If you use wbemFlagForwardOnly (32), you can't use colItems.Count and you
can enumerate it only once:


Set colItems = objWMIService.ExecQuery _
("Select * from Win32_Battery", , _
wbemFlagReturnImmediately + wbemFlagForwardOnly)

WScript.Echo TypeName(colItems)
'WScript.Echo colItems.Count

For Each objItem In colItems
WScript.Echo objItem.Name
Next


If you use wbemFlagReturnImmediately and there is an error, it is reported
only when you try to use colItems


Set colItems = objWMIService.ExecQuery _
("Select * from Win32_InvalidClass", , _
wbemFlagReturnImmediately + wbemFlagForwardOnly)

' The error is reported here
For Each objItem In colItems
WScript.Echo objItem.Name
Next


If you use wbemFlagReturnWhenComplete (0) the error is reported on ExecQuery
call:


' The error is reported here
Set colItems = objWMIService.ExecQuery _
("Select * from Win32_InvalidClass", , _
wbemFlagReturnWhenComplete)

For Each objItem In colItems
WScript.Echo objItem.Name
Next


--
urkec

"urkec" <urkec@xxxxxx> wrote in message
news:9C202CA9-CFF3-4D6D-995C-B03656B668AA@xxxxxxTo me that indicates the 32 flag means 'Please, please, please, give me the
most obstinate, useless type of collection'. Why would anyone knowingly ask
for this? Is it quicker, use less resourses, or ???

-Paul Randall

"Paul Randall" <paulr90@xxxxxx> wrote in message
news:ORgXYr%239IHA.3344@xxxxxxThanks to ekkehard.horner, I found the answer at
http://msdn.microsoft.com/en-us/libr...80(VS.85).aspx. For scripts
posted in a support group, I think I would avoid the 32 flag to make the
collection more user friendly when the user modifies the code to understand
it better.

-Paul Randall