Vista - GetRows question...

I am attempting to extract a column of data from SQL and store it into an
array. When I attempt to display the array's contents, I don't see the
results. Here is my code:

'Create the Recordset
strSQL = "SELECT month FROM graph_LM_time_all "

'Open the Recordset
objRS.Open strSQL, objConn

'Create the Array
Dim myArray
myArray = objRS.GetRows()

'Loop through the Array and write the results
Dim i
For i=0 to UBound(myArray)
Response.Write myArray(i,0) & "<br />"
Next

I get no results returned. What am I missing?

You have to loop though the elements of the result set to get the
data.

"Ken D." <KenD@xxxxxx> wrote in message
news:5BC23987-1C83-4E94-ACA4-0470262F7B38@xxxxxxadd this and tell us what it displays:

response.write "[" & ubound(myArray) & "]"
Also, is myArray a one-dimensional array, or a two-dimensional one?

/Al

Ken D. schrieb:..GetRows returns a two dimensional array: first dimension cols,
second dimension rows. See:

Dim oFS : Set oFS = CreateObject( "Scripting.FileSystemObject" )
Dim sTDir : sTDir = oFS.GetAbsolutePathName( ".\adotext" )
Dim sTable : sTable = "jmastrianb"
Dim sCS : sCS = Join( Array( _
"Provider=MSDASQL.1" _
, "Driver={Microsoft Text Driver (*.txt; *.csv)}" _
, "DBQ=" & sTDir _
), ";" )
Dim oCN : Set oCN = CreateObject( "ADODB.Connection" )
oCN.Open sCS
Dim sSQL : sSQL = "SELECT * FROM [" & sTable & ".txt]"
Dim oRS : Set oRS = oCN.Execute( sSQL )

Dim aData : aData = oRS.GetRows()
WScript.Echo "cols:", UBound( aData, 1 ) + 1
WScript.Echo "rows:", UBound( aData, 2 ) + 1
Dim nRow
For nRow = 0 To UBound( aData, 2 )
Dim nCol
For nCol = 0 To UBound( aData, 1 )
WScript.Echo nRow, nCol, aData( nCol, nRow )
Next
WScript.Echo
Next

oRS.Close
oCN.Close

output:

=== demoGetRows: demo .GetRows() =======
cols: 3
rows: 4
0 0 123
0 1 7654321
0 2 123456789

1 0 12
1 1 Joe
1 2 Bellmonts

2 0 1
2 1 A
2 2 Short

3 0 33
3 1 Deborah
3 2 Whereever

=== demoGetRows: 0 done (00:00:01) =====