Vista - Build a tag list of a database column

Hello, I have a column called newstext in an access database.

I would like to build a Tag list that consist of most words in a textfile. I would like to count how many times they occur, and
maybe how many times they occur in relations to another tag.

Do anybody have any tips for how to proceed on this one?

--
-- HAL07, Engineering Services, Norway

HAL07 wrote:
In VBScript I would use a dictionary object. The Exists method ensures
uniqueness. The key value would be the case insensitive word, the item value
would be the number of occurrences. Perhaps something similar to:
===========
Set objWordList = CreateObject("Scripting.Dictionary")
objWordList.CompareMode = vbTextCompare

strText = "This is a test consisting of a few lines" _
& vbCrLf & "of words. Words are delimited by spaces," _
& vbCrLf & "punctuation, and carriage returns. There are" _
& vbCrLf & "many possible punctuation marks, so it is" _
& vbCrLf & "important to account for all possibilities." _
& vbCrLf & "The expected result is a count of how many times" _
& vbCrLf & "Each word occurs in the text."

' Create array of lines delimited by carriage returns.
arrLines = Split(strText, vbCrLf)
' Enumerate lines.
For Each strLine In arrLines
' Remove punctuation.
strLine = Replace(strLine, ".", "")
strLine = Replace(strLine, ",", "")
strLine = Replace(strLine, ";", "")
strLine = Replace(strLine, ":", "")
strLine = Replace(strLine, "?", "")
strLine = Replace(strLine, "-", "")
strLine = Replace(strLine, "!", "")
' Create array of words delimited by spaces.
arrWords = Split(strLine, " ")
' Enumerate words in the line.
For Each strWord In arrWords
' Check if the word has been encountered before.
If (objWordList.Exists(strWord) = True) Then
' Increment count for this word by one.
objWordList(strWord) = objWordList(strWord) + 1
Else
' Add this word to the dictionary object with a count of one.
objWordList(strWord) = 1
End If
Next
Next

' Enumerate all words and their counts in parentheses.
For Each strWord In objWordList.Keys
Wscript.Echo strWord & " (" & objWordList(strWord) & ")"
Next
========
You might want to make all words lower case. Then you could add:

strLine = LCase(strLine)

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

Richard Mueller [MVP] wrote:thank you very much. i will look into it.


--
-- HAL07, Engineering Services, Norway