Vista - Swap first and last part of a filename : how ?

Hi,

I would like to rename a bunch of 250 files by swapping firts and last part
of the filename

files are now named in a work - composer scheme
i need them to be named according to composer - work scheme

All are in same folder

Any way to achieve this programaticaly ( or with an utility ???)


TIA !!!!!!!!!

"MoiMeme" <antispam@xxxxxx> wrote in message
news:ujV1rT7eJHA.5408@xxxxxxCan you post a few examples of the filenames, please? Seeing a few
filename examples will help determine if there are any character(s) that can
use as a reliable delimiter.

"MoiMeme" <antispam@xxxxxx> wrote in message
news:ujV1rT7eJHA.5408@xxxxxxYou can use the FileSystemObject to enumerate the files, parse the names,
and rename. For example, if the file names are similar to:

First Last.txt

then someting similar to below should work:
=========
Option Explicit

Dim objFSO, objFolder, colFiles, objFile
Dim strName, strBase, strExtension, arrNames
Dim intIndex, blnChanged

Set objFSO = CreateObject("Scripting.FileSystemObject")

' Enumrate all files in specified folder.
Set objFolder = objFSO.GetFolder("c:\rlm\Scripts\RenameFiles")
Set colFiles = objFolder.Files
For Each objFile In colFiles
' Retrieve file name.
strName = objFile.Name
' Keep track if file is to be renamed.
blnChanged = False
' Find "." in name.
intIndex = InStr(strName, ".")
If (intIndex > 0) Then
' Parse base name and extension.
strBase = Left(strName, intIndex - 1)
strExtension = Mid(strName, intIndex + 1)
Else
strBase = strName
strExtension = ""
End If
' Parse base name for two names delimited by a space.
arrNames = Split(strBase, " ")
' If there are two names, reverse them.
If (UBound(arrNames) = 1) Then
strBase = arrNames(1) & " " & arrNames(0)
blnChanged = True
End If
' If names reversed, rename the file
If (blnChanged = True) Then
strName = strBase & "." & strExtension
objFile.Name = strName
End If
Next

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

Filenames are in following format : "work - composer". Allways a space then
'-' then again a space

"Richard Mueller [MVP]" <rlmueller-nospam@xxxxxx> a écrit dans
le message de news: e1Vkyb%23eJHA.5956@xxxxxx

Then replace this part of the code I posted:
==========
' Parse base name for two names delimited by a space.
arrNames = Split(strBase, " ")
' If there are two names, reverse them.
If (UBound(arrNames) = 1) Then
strBase = arrNames(1) & " " & arrNames(0)
blnChanged = True
End If
==========
with this:
==========
' Parse base name for two names delimited by " - ".
arrNames = Split(strBase, " - ")
' If there are two names, reverse them.
If (UBound(arrNames) = 1) Then
strBase = arrNames(1) & " - " & arrNames(0)
blnChanged = True
End If
==========

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

"MoiMeme" <antispam@xxxxxx> wrote in message
news:eWLa3w%23eJHA.1172@xxxxxx

Thanks !

"Richard Mueller [MVP]" <rlmueller-nospam@xxxxxx> a écrit dans
le message de news: eGJr33%23eJHA.3456@xxxxxx