Vista - Will not work in Vista

Can someone identify and provide guideance to why the following script will
not run?
It runs great on XP

On Error Resume Next

Const HKEY_LOCAL_MACHINE = &H80000002
dim vbYesNo
dim vbQuestion
vbYesNo = 4
vbQuestion = 48

'Create inputbox in order to collect the computer Name
'----------------------------

StrComputer=InputBox("Enter Name of the Remote Computer...","Connect to
Remote Computer")

'Connect to the Remote Registry using WMI space
'I assume that you have administrative rights ?
'---------------------------------

Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" & _
strComputer & "\root\default:StdRegProv")

'Error handling...if not able to connect to the remote machine...you will
be notified
'---------------------------------------------------------

If Err.Number <> 0 Then
MsgBox "Error. Computer not accessible...Possible reasons" & vbcrlf &
vbcrlf &_
"1. The computer name is incorrect" & vbcrlf & _
"2. Your too stupid to use the script" & vbcrlf & _
"3. The computer is not running... " & vbcrlf & _
"4. The currently logged-on user has no admin rights"& vbcrlf &
vbcrlf &_
"End of Script",64,"An Error occured"
WScript.Quit()
End If

'to disable CAC Login requirement,
'registry key
HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System\scforceoption
'should be set to 0

strKeyPath = "SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System"
strValueName = "scforceoption"
dwValue = 0
oReg.SetDWORDValue HKEY_LOCAL_MACHINE,strKeyPath,strValueName,dwValue

WScript.echo " Action completed sucessfully "

"La" <La@xxxxxx> wrote in message
news:A7B6BFC3-3A54-4F3A-89A2-13BCF05CF4AC@xxxxxxPerhaps if you would indicate what happens when you attempt to run it, that
would make it easier for us to narrow things down for you...

/Al

"La" <La@xxxxxx> wrote in message
news:A7B6BFC3-3A54-4F3A-89A2-13BCF05CF4AC@xxxxxxFirst off, it should help to specify authentication level. Use:

Set oReg = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate,authenticationLevel=Pkt}!\\" _
& strComputer & "\root\default:StdRegProv")

Otherwise, we need to know the error message and the statement that raised
the error. For that, only use "On Error Resume Next" for the one statement
where you trap errors. For example, remove your "On Error Resume Next"
statement, then you could use:
=========
On Error Resume Next
Set oReg = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate,authenticationLevel=Pkt}!\\" _
& strComputer & "\root\default:StdRegProv")
If Err.Number <> 0 Then
' Restore normal error handling.
On Error GoTo 0
MsgBox "Error. Computer not accessible...Possible reasons" & vbcrlf &
vbcrlf & _
"1. The computer name is incorrect" & vbcrlf & _
"2. Your too stupid to use the script" & vbcrlf & _
"3. The computer is not running... " & vbcrlf & _
"4. The currently logged-on user has no admin rights" & vbcrlf &
vbcrlf & _
"End of Script", 64, "An Error occured"
WScript.Quit()
End If

' Restore normal error handling.
On Error GoTo 0
===========

Actually, when I copied your MsgBox statement I thought it had errors (which
I corrected). That's why I restored normal error handling even before the
MsgBox statement, and you don't use the Err object anyway. Better still
would be the following, which would display the exact error, not a guess:
==========
On Error Resume Next
Set oReg = GetObject("winmgmts:" _
& "{impersonationLevel=impersonate,authenticationLevel=Pkt}!\\" _
& strComputer & "\root\default:StdRegProv")
If (Err.Number <> 0) Then
Call MsgBox("Error number: " & Err.Number _
& vbCrLf & "Description: " & Err.Description _
& vbCrLf & "Source: " & Err.Source, _
vbCritical + vbOKOnly, "Error connecting")
Wscript.Quit
End If

' Restore normal error handling.
On Error GoTo 0
===========
Note that I don't restore normal error handling just before the MsgBox
statement now because I use the Err object, which would be cleared by the
"On Error GoTo 0" statement. Now if an error occurs elsewhere you will get
an error message.

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

Works like a charm - I received an error due to my not having permissions
(received an error 70), but other users with permission are able to
successfully use it now.

Danke

"Richard Mueller [MVP]" wrote: