Vista - Finding members of RDP groups of a list of computers

got the script to work by double clicking the vbs file. Thanks again. if i
want this to output to a txt file, what lines of code would i add to the the
..vbs file for it to work when also double clicking on it rather than running
cscript //nologo RDPMembers.vbs > report.txt from the command prompt?

"Richard Mueller [MVP]" wrote:

"dave" <dave@xxxxxx> wrote in message
news63F1F90-9339-4C1E-9E86-841D95D11CE7@xxxxxxA version of the program that writes to a text file (instead of echoing to
the command console):
==========
Option Explicit

Dim objFSO, strFile, objFile
Dim strComputer, objGroup, objMember
Dim strReport, objReport

Const ForReading = 1
Const ForWriting = 2
Const OpenAsASCII = 0
Const CreateIfNotExist = True

' Open text file with NetBIOS names of computers.
strFile = "c:\Scripts\computers.txt"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(strFile, ForReading)

' Open output file to write results.
Set objReport = objFSO.OpenTextFile(strReport, _
ForWriting, CreateIfNotExist, OpenAsASCII)

' Read file of computer names.
Do Until objFile.AtEndOfStream
strComputer = Trim(objFile.ReadLine)
' Skip blank lines.
If (strComputer <> "") Then
' Write computer name to output file.
objReport.WriteLine "Computer: " & strComputer
Set objGroup = GetObject("WinNT://" & strComputer _
& "/Remote Desktop Users,group")
For Each objMember In objGroup.Members
' Write group member names to output file.
objReport.WriteLine objMember.Name
Next
End If
Loop

' Clean up.
objFile.Close
objReport.Close
========
You can also modify this so the computer names and the members of the group
for that computer are on one comma delimited line. This file could then be
read by a spreadsheet program. This version would be as below:
==========
Option Explicit

Dim objFSO, strFile, objFile
Dim strComputer, objGroup, objMember
Dim strReport, objReport, strOutput

Const ForReading = 1
Const ForWriting = 2
Const OpenAsASCII = 0
Const CreateIfNotExist = True

' Open text file with NetBIOS names of computers.
strFile = "c:\Scripts\computers.txt"
Set objFSO = CreateObject("Scripting.FileSystemObject")
Set objFile = objFSO.OpenTextFile(strFile, ForReading)

' Open output file to write results.
Set objReport = objFSO.OpenTextFile(strReport, _
ForWriting, CreateIfNotExist, OpenAsASCII)

' Read file of computer names.
Do Until objFile.AtEndOfStream
strComputer = Trim(objFile.ReadLine)
' Skip blank lines.
If (strComputer <> "") Then
' Document computer name.
strOutput = strComputer
Set objGroup = GetObject("WinNT://" & strComputer _
& "/Remote Desktop Users,group")
For Each objMember In objGroup.Members
' Write group member names to output file.
' Document group member names.
strOutput = strOutput & "," & objMember.Name
Next

' Write computer and group member names to output file in one
' comma delimited line.
objReport.WriteLine strOutput
End If
Loop

' Clean up.
objFile.Close
objReport.Close

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

Does this work if i name these as .vbs and double click them? i'm getting
errors when i do that?

"Richard Mueller [MVP]" wrote:

Sorry, I forgot to assign a value to variable strReport. This should be the
file name and path of the log file to be created by the program. For
example:

' Open output file to write results.
strReport = "c:\Scripts\report.txt"
Set objReport = objFSO.OpenTextFile(strReport, _
ForWriting, CreateIfNotExist, OpenAsASCII)

Note the additional statement that assigns the value to strReport. This
would apply to both programs I posted. The file name and path should be
modified for your situation. Also you should modifity the value of strFile
for your situation, the file that contains the computer names.

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

"dave" <dave@xxxxxx> wrote in message
news:005A3491-F624-4359-AB36-D43BC1FEA006@xxxxxx