Vista Tutorial - working LDAP query, well almost.. 800A000D

Hello all,

The following script should get 2 properties form the Administrator user:
"sAMAccountName" and "description".
It does display the sAMAccountName but throws an error when it tries to
display the user description.

The code:
Set objRootDSE = GetObject("LDAP://RootDSE")
strDomainDN = objRootDSE.Get("DefaultNamingContext")
Set objConn = CreateObject("ADODB.Connection")
objConn.Provider = "ADsDSOObject"
objConn.Open "Active Directory Provider"

Set objRSUserDescr = objConn.Execute("<LDAP://" & strDomainDN &
">;(&(objectClass=user)(sAMAccountName=Administrator));sAMAccountName,description;subtree")

WScript.echo objRSUserDescr.Fields(0).Value
WScript.echo objRSUserDescr.Fields(1).Value


The error:
this line: WScript.echo objRSUserDescr.Fields(1).Value
Error: Type Mismatch
Code: 800A000D

I tried CStr(objRSUserDescr.Fields(1).Value), but get the same error.
In my case, I cannot use GetObject("LDAP://" & UserDN) to get the user
description. I have to query AD directly.

Anyone an idea what goes wrong ?

thanks in advance,
Sander

"Sander" <Sander@xxxxxx> wrote in message
news:uqN2$YP8JHA.5424@xxxxxxI believe this property is an array. Change your line to:

WScript.echo Join(objRSUserDescr.Fields(1).Value, vbCrLf)

You are right!
How silly of me (I tried IsNull IsEmpty etc, but not IsArray

It works like a charm!

lots of Thanks!
Sander


"James Whitlow" <jwhitlow.60372693@xxxxxx> wrote in message
news:%23%23d1ydP8JHA.1376@xxxxxx

The description attribute is a strange one, because technically it is
multi-valued, even though there is never more than one value. ADO retrieves
it as an string array with one value, or a Null if there is no value
assigned.

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

"Sander" <Sander@xxxxxx> wrote in message
news:ucWBphP8JHA.3544@xxxxxx

"Richard Mueller [MVP]" <rlmueller-nospam@xxxxxx> wrote in
message news:ee8CVqP8JHA.5400@xxxxxxSander, to Richard's point, you should probably do an IsArray test before
using the Join method to prevent an exception in the event that it is empty.

sDescription = objRSUserDescr.Fields("description").Value

If IsArray(sDescription) Then
sDescription = Join(sDescription, Empty)
Else
sDescription = Empty
End If

WScript.Echo sDescription

"James Whitlow" <jwhitlow.60372693@xxxxxx> wrote in message
news:%23ba8eAQ8JHA.1336@xxxxxxAgreed. Another option is to use IsNull, since if this returns False, the
value is an array. I use code similar to:
====
If IsNull(sDescription) Then
sDescription = ""
Else
For Each sItem In sDescription
sDescription = sItem
Next
End If
======
The Join function actually looks cleaner than the For Each loop I use. I
generally the the For Each loop when I deal with other multi-valued
attributes, but in this case the Join is better.

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

When in doubt, have VBScript tell you about the variable. Functions
Typename and/or Vartype would have given you the array clue.

-Paul Randall

"Sander" <Sander@xxxxxx> wrote in message
news:ucWBphP8JHA.3544@xxxxxx

Thats exactly what i did ;]

Thanks again James & Richard!



"James Whitlow" <jwhitlow.60372693@xxxxxx> wrote in message
news:%23ba8eAQ8JHA.1336@xxxxxx