Vista - Pop-up message...

In using this script to pop-up a Windows message...

----------
strTitle="INSERT_WINDOW_TITLE_HERE"

Dim WSHShell
Set WSHShell=WScript.CreateObject("WScript.Shell")

WSHShell.Popup"INSERT_WINDOW_MESSAGE_TEXT_HERE",3,strTitle
----------

How can I get this message window to appear with no buttons?

Thanx.

"Steven Sinclair" <StevenSinclair@xxxxxx> wrote in
message news:C6CA38D6-798C-4EB8-82CB-166F4463B552@xxxxxxSorry, you can't under VB Script.

So, then, what are my options? I'm merely trying to display an
automatically-timing out informational message to the user. I simply don't
want any user interaction other than the display of the actual message.

Thanx.

"Pegasus [MVP]" wrote:

You could write your own C++ program to generate a pop-up message.
Alternatively you could use this script. It isn't elegant but it works . . .

Set WSHShell=WScript.CreateObject("WScript.Shell")
iTime = Timer
Do
WSHShell.Popup "Hello World",10,"Test message"
If timer - itime >= 10 then Exit Do
Loop


"Steven Sinclair" <StevenSinclair@xxxxxx> wrote in
message news:52748538-4FE2-4C49-9971-2BB9A7626D40@xxxxxx

Nope. That one still shows a user-clickable button. In addition, this one
shows the message, goes away, then comes right back...endless loop.

I just want to be able to have no buttons on the window.

Thanx.

"Pegasus [MVP]" wrote:

"Steven Sinclair" <StevenSinclair@xxxxxx> wrote in
message news:3F0216D8-37C5-4626-A84A-A30B701FDC92@xxxxxxYou better have another look. It's not an endless loop - the message
disappears after the prescribed time-out and it basically "ignores"
button-presses. As I said before, there is no VB Script function without
some button. If you don't like it then you have to code your own pop-up
program.

"Steven Sinclair" <StevenSinclair@xxxxxx> wrote in
message news:52748538-4FE2-4C49-9971-2BB9A7626D40@xxxxxxThe code you posted displays the message for 3 seconds and then goes away on
it's own. "With no buttons" sounds like you want to create a nag screen
which the user can not dismiss.

'NagPopup.vbs
Option Explicit

Dim NagTime, Nag, Msg, Title, WSHShell
NagTime = 5 'Seconds to nag user

Set WshShell = WScript.CreateObject("WScript.Shell")
Nag = DateAdd("s", NagTime, Now())
Title = "Be patient:"

Do
Msg = "This nag message will go away in " & CStr(NagTime) & " seconds."
'Replace NagTime below with 1 for an anoying countdown.
WshShell.Popup Msg, NagTime, Title, 16
NagTime = DateDiff("s", Now(), Nag)
Loop While Nag > Now

--
Todd Vargo
(Post questions to group only. Remove "z" to email personal messages)

Steven Sinclair wrote:hi Steve,

As you know, the "Graphical User Interface" (GUI) available
to vbs scripters is severely limited. Other that msgboxes
and askboxes, the only other option is IE (used as a dialog).

Once upon a time, it was possible to "de-chrome" IE (that is,
remove everything about IE except the client area) so that just
some text could be shown. But apparently ms felt that showing
un-identified messages on the screen was inappropriate, and so
removed that capability.

However, there are 3rd-party controls which allow for an almost
full vb-like GUI interface to be used. If you are courageous
enough (or foolhardy enough) to use a third-party control,
then here is an example that will show only a message on
the screen, using "KixForms"

--- <code> ---
' demo of a KixForms GUI for scripting. 01July09
' Note that KixForms is intended for the KIX Language,
' but works perfectly well with vbs too.
' KixForms may be found here: http://www.kixforms.org/
' and was written by: Shawn Tassie of CGI Canada
'
' This is a rather stilted demo, in that it is intended
' to just show a single line of text on the screen,
' and nothing else. It does this by showing a "form"
' with a "bare" titlebar that contains the message.
' Note also, there is no button shown allowing the
' user to cancel this dialog, (unless he/she is
' fairly knowledgeable)...
' ------------------------------------------------
Option Explicit

Dim oKSF : Set oKSF = CreateObject("Kixtart.System")

Dim oForm : Set oForm = oKSF.Form()

With oForm
.Text = "Hi User, your IT staff will now install Windows 7... "
.Width = 300 ' wd in pixels
.Height = 30 ' ht in pixels
.MinimizeBox = False
.MaximizeBox = False
.ControlBox = False ' a.k.a. the "Close Button" [X]
.Center
End With

oForm.Show

Dim tSecs : tSecs = 0
Const timerLimit = 5 ' seconds

Do
WScript.Sleep 1000 ' sleep one second
tSecs = tSecs + 1
Loop While (tSecs < timerLimit)
oForm.Hide

MsgBox("vbs script quitting now... ")
WScript.Quit
--- <end code> ---

cheers, jw
____________________________________________________________

You got questions? WE GOT ANSWERS!!! ..(but, no guarantee
the answers will be applicable to the questions)


p.s. There is another "Forms" capability called wshDialog,
written by: Peter J.C. van der Klugt, which may be found here:

http://home.hccnet.nl/p.vd.klugt/