Vista - Map network printers based on OU user is in within Active Director

Let us know what you find, I'm kinda curious myself what some numbers behind
it would look like.

"Mark D. MacLachlan" wrote:

The advantage of the code I posted is that you bind to just one object in
AD, then retrieve all direct group memberships. However, the memberOf
collection is a collection of Distinguished Names (DN's). Once all the names
are loaded into the dictionary object, it is very easy to check for a DN,
using the Exists method. Yes, this involves an If/Then/End If construction
for each group you check. I see no way to use a Select Case.

Using the "pre-Windows 2000" name of the groups looks cleaner, but only to
you as you read the script. The "pre-Windows 2000" name is the value of the
sAMAccountName attribute. More code is required to retrieve this value. You
could bind to each group object, but that slows down the script, especially
if there are many groups to check. If you want to use the sAMAccountName, it
would be more efficient to use the NameTranslate object to convert the DN
into the sAMAccountName. For example (not tested):
============
Option Explicit

Dim objSysInfo, objUser, strUserDN
Dim objGroupList, colstrGroups, strDN
Dim objNetwork, strNTGroup, strGroup
Dim objTrans

' Constants for the NameTranslate object.
Const ADS_NAME_INITTYPE_GC = 3
Const ADS_NAME_TYPE_NT4 = 3
Const ADS_NAME_TYPE_1779 = 1

' Bind to current user object.
Set objSysInfo = CreateObject("ADSystemInfo")
strUserDN = objSysInfo.UserName
Set objUser = GetObject("LDAP://" & strUserDN)

' Create dictionary object to track groups.
Set objGroupList = CreateObject("Scripting.Dictionary")
objGroupList.CompareMode = vbTextCompare

' Use the NameTranslate object to convert names.
Set objTrans = CreateObject("NameTranslate")
' Initialize NameTranslate by locating the Global Catalog.
objTrans.Init ADS_NAME_INITTYPE_GC, ""

' Retrieve group memberships (Distinguished Names).
colstrGroups = objUser.memberOf
Select Case TypeName(colstrGroups)
Case "String"
' One group DN in collection.
' Use Set method to specify DN.
objTrans.Set ADS_NAME_TYPE_1779, colstrGroups
' Use Get method to retrieve NT format of the name.
' This will be in the form DomainName\GroupName.
strNTGroup = objTrans.Get(ADS_NAME_TYPE_NT4)
' Parse for the group name (sAMAccountName).
strGroup = Mid(strNTGroup, InStr(strNTGroup, "\") + 1)
objGroupList.Add strGroup, True
Case "Variant()"
' More than one group DN in collection.
For Each strDN In colstrGroups
' Use Set method to specify DN.
objTrans.Set ADS_NAME_TYPE_1779, strDN
' Use Get method to retrieve NT format of the name.
' This will be in the form DomainName\GroupName.
strNTGroup = objTrans.Get(ADS_NAME_TYPE_NT4)
' Parse for the group name (sAMAccountName).
strGroup = Mid(strNTGroup, InStr(strNTGroup, "\") + 1)
objGroupList.Add strGroup, True
Next
Case "Empty"
' No group DN's.
End Select

' Map printer per group membership. Repeat for each group.
Set objNetwork = CreateObject("Wscript.Network")
If objGroupList.Exists("TestGroup") Then
objNetwork.AddWindowsPrinterConnection "\\PrintServer\HPLaser2"
objNetwork.SetDefaultPrinter "\\PrintServer\HPLaser2"
End If
========
There is a lot more code now, but it does not mean the script is slow or
inefficient. The NameTranslate and Dictionary objects are local.
NameTranslate is very efficient at converting names. The extra conversion
slows things a bit, but much less than binding to the group objects would.

--
Richard Mueller
MVP Directory Services
Hilltop Lab - http://www.rlmueller.net
--

"Rich" <richjone@xxxxxx> wrote in message
news:917820B3-8C37-44E6-94E6-4342713BE1EC@xxxxxx

Richard Mueller [MVP] wrote:
Richard, why not gather the information into the dictionary object,
then enumerate all the keys of the dictionary and then you could use a
select case.


For Each Key in oDic.Keys
Select Case Key
Case Foo
objNetwork.AddWindowsPrinterConnection "\\PrintServer\HPLaser2"
objNetwork.SetDefaultPrinter "\\PrintServer\HPLaser2"Next
End Select
Next

Best regards,

Mark
--

I'm more concerned about the user experience than my ease of reading the
script. so the code I pasted before and my assumption about copying the if
statement over and over was right? or is it actually an if then if then
if....end type deal? I've never made one of those before.

"Richard Mueller [MVP]" wrote: