Vista - Remove update history

control panel/system and maintenance/windows update/view update history

I have a number of failed updates for various reasons. I would like to
delete them and leave the list of successful updates. Is this possible?
Thanks.

No, probably not, but if you want what was successful, open a command prompt
and run 'systeminfo'
e.g.
systeminfo > c:/success.txt

--
Was this helpful? Then click the "Yes" Ratings button. Voting helps the web
interface.
http://www.microsoft.com/wn3/locales....htm#RateAPost

Mark L. Ferguson

..
"ADKR" <ADKR@xxxxxx> wrote in message
news1DEA04F-6213-4E44-A2EF-33CD94B8B7BE@xxxxxx

Hi,

Mark's way works, but I had to run the command prompt a Administrator.

For more information on what was successful and which failed along with a
description of each. Open Notepad and Copy/Paste the following...
Save/As Updates.vbs Credit goes to Author: Torgeir Bakken for this
script.

Start Copy Below
========================================


' Script that reports installed updates that are
' installed with Windows Update v5 technology
'
' Result will be written to %temp%\UpdateHistory.txt
' and then launched in Notepad
'
' Author: Torgeir Bakken
' Date 2004-08-12
'
Option Explicit


Const OverwriteIfExist = -1
Const OpenAsASCII = 0


Dim oWU, iTHCount, colUpdate, oUpdate, sStatus, iTotal
Dim iSuccess, iFailed, iAborted, iUnknown, sErrorCode
Dim oFSO, oShell, sFile, f


On Error Resume Next
Set oWU = CreateObject("Microsoft.Update.Searcher")


If Err.Number <> 0 Then
MsgBox "WU5 programming interface does not exist.", _
vbInformation + vbSystemModal, "Update history"
WScript.Quit
End If
On Error Goto 0


iTHCount = oWU.GetTotalHistoryCount
If iTHCount > 0 Then


Set oFSO = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("Wscript.Shell")
sFile = oShell.ExpandEnvironmentStrings("%TEMP%") & "\UpdateHistory.txt"
Set f = oFSO.CreateTextFile(sFile, _
OverwriteIfExist, OpenAsASCII)


iTotal = 0
iSuccess = 0
iFailed = 0
iAborted = 0
iUnknown = 0


f.WriteLine "Report run at " & Now
f.WriteLine "---------------------------------" _
& "---------------------------------"


Set colUpdate = oWU.QueryHistory(0, iTHCount)


For Each oUpdate In colUpdate
f.WriteLine "Title:" & vbTab & vbTab & vbTab & oUpdate.Title
f.WriteLine "Description:" & vbTab & vbTab & oUpdate.Description
f.WriteLine "Date/Time in GMT:" & vbTab & oUpdate.Date
f.WriteLine "Install mechanism:" & vbTab & oUpdate.ClientApplicationID


sErrorCode = ""
Select Case oUpdate.ResultCode
Case 2
sStatus = "Succeeded"
iSuccess = iSuccess + 1
Case 4
sStatus = "Failed"
iFailed = iFailed + 1
sErrorCode = oUpdate.UnmappedResultCode
Case 5
sStatus = "Aborted"
iAborted = iAborted + 1
Case Else
sStatus = "Unknown"
iUnknown = iUnknown + 1
End Select


If sStatus = "Failed" Then
f.WriteLine "Install error:" & vbTab & vbTab & sErrorCode
End If


f.WriteLine "Install status:" & vbTab & vbTab & sStatus
f.WriteLine "---------------------------------" _
& "---------------------------------"


iTotal = iTotal + 1
Next


f.WriteLine
f.WriteLine "Total number of updates found: " & iTotal
f.WriteLine "Number of updates succeeded: " & iSuccess
f.WriteLine "Number of updates failed: " & iFailed
f.WriteLine "Number of updates aborted: " & iAborted


f.Close
oShell.Run "notepad.exe " & """" & sFile & """", 1, False
Else


MsgBox "No entries found in Update History.", _
vbInformation + vbSystemModal, "Update history"


End If


=======================================
End Copy Above

--
All the best,
SG

ALEX NICHOL
(1935-2005)
http://www.aumha.org/alex.htm
You will never be forgotten my friend

"ADKR" <ADKR@xxxxxx> wrote in message
news1DEA04F-6213-4E44-A2EF-33CD94B8B7BE@xxxxxx

"ADKR" wrote in message
news1DEA04F-6213-4E44-A2EF-33CD94B8B7BE@xxxxxx
You want to look here...

Control Panel > Programs > Programs and Features > View Installed Updates

If it failed there's nothing to delete/uninstall.

<here@xxxxxx> wrote in message
news:%23zQGJgffIHA.2268@xxxxxx

Thanks everyone for taking a shot at this. My issue, deleting failed updates
from the list described below looks like a bust. I don't want to
uninstall/view/whatever. I just want to delete the list/notifications/titles
of failed installs. It isn't earth shaking, just an annoyance.

"ADKR" wrote: