Solved Script to parse .txt & move Computer Accounts to different OU

[humtake]

Not sure where to post this.

I am trying to run the script from here:

http://www.vistax64.com/vb-script/260330-script-parse-txt-move-computer-accounts-different-ou.html

I am getting the same error the user was getting in the OP, but he does not give the answer how it was fixed. I'd like to find out if anyone knows how to get rid of that error.

 

[niemiro]

re: Script to parse .txt & move Computer Accounts to different OU

Try this, report back I probably have not got it right first time, but have corrected two syntax errors.

Option Explicit

Dim strFile, strTargetOU, objFSO, objFile, objOU

Dim objRootDSE, strDNSDomain, objTrans, strNetBIOSDomain

Dim strComputer, strComputerDN, objComputer

Const ADS_NAME_INITTYPE_DOMAIN = 1

Const ADS_NAME_TYPE_NT4 = 3

Const ADS_NAME_TYPE_1179 = 1

' Specify text file of computer NetBIOS names.

strFile = "c:\Computers.txt"

' Specify target OU to move computer objects into.

strTargetOU = "ou=SrAccounts,dc=MyDomain,dc=com"

' Open the file for read access.

Set objFSO = CreateObject("Scripting.FileSystemObject")

Set objFile = objFSO.OpenTextFile(strFile, 1)

' Bind to the target OU.

Set objOU = GetObject("LDAP://" & strTargetOU)

' Determine DNS domain name from RootDSE object.

Set objRootDSE = GetObject("LDAP://RootDSE")

strDNSDomain = objRootDSE.Get("DefaultNamingContext")

' Use the NameTranslate object to find the NetBIOS domain name from

' the DNS domain name.

Set objTrans = CreateObject("NameTranslate")

objTrans.Init ADS_NAME_TYPE_NT4, strDNSDomain

objTrans.Set ADS_NAME_TYPE_1179, strDNSDomain

strNetBIOSDomain = objTrans.Get(ADS_NAME_TYPE_NT4)

' Remove trailing backslash.

strNetBIOSDomain = Left(strNetBIOSDomain, Len(strNetBIOSDomain) - 1)

' Use the NameTranslate object to convert computer NetBIOS

' names to Distinguished Names.

objTrans.Init ADS_NAME_INITTYPE_DOMAIN, strNetBIOSDomain

' Read lines from the file.

Do Until objFile.AtEndOfStream

strComputer = Trim(objFile.ReadLine)

If (strComputer <> "") Then

' Convert NetBIOS name to DN.

' NetBIOS name must have "$" appended to end.

' Trap error if computer not found.

On Error Resume Next

objTrans.Set ADS_NAME_TYPE_NT4, strNetBIOSDomain & "\" & strComputer & "$"

If (Err.Number <> 0) Then

On Error Goto 0

Wscript.Echo "Computer not found: " & strComputer

Else

On Error GoTo 0

strComputerDN = objTrans.Get(ADS_NAME_TYPE_1179)

' Bind to the computer object.

Set objComputer = GetObject("LDAP://" & strComputerDN)

' Move the computer object to the target OU.

objTargetOU.MoveHere objComputer.AdsPath, vbNullString

End If

End If

Loop

Wscript.Echo "Done"

 

[humtake]

re: Script to parse .txt & move Computer Accounts to different OU

Thanks for the quick reply!!

Now I'm getting this:

Line: 97
Char: 1
Error: Variable is undefined: 'objTargetOU'

Obviously, that means there is no declaration. However, since that is the only instance of objTargetOU in the script, I'm not sure if that is supposed to be in the Dim or not.

 

[niemiro]

re: Script to parse .txt & move Computer Accounts to different OU

Thanks for the quick reply!!

Now I'm getting this:

Line: 97
Char: 1
Error: Variable is undefined: 'objTargetOU'

Obviously, that means there is no declaration. However, since that is the only instance of objTargetOU in the script, I'm not sure if that is supposed to be in the Dim or not.

I hate VB with a passion. What is going on in this script exactly? Do you think that you are supposed to add it into the Dim manually, based on the name of the computer to move to, which the original code writer could not know, or have you put that somewhere in the text file? That would be my guess: you are meant to put it in the Dim yourself, with a value. What do you think? I am useless with VBScript. Trying to put DirectX knowledge into VBScript. Hmmm.

 

[humtake]

re: Script to parse .txt & move Computer Accounts to different OU

I fixed it from your changes. I changed objTargetOU to objOU which was already declared and it works. Thanks for getting me passed the initial error, I would have pulled out the hairs on my chest trying to figure this one out...I'm already bald from other scripts. :-)

 

[niemiro]

re: Script to parse .txt & move Computer Accounts to different OU

I fixed it from your changes. I changed objTargetOU to objOU which was already declared and it works. Thanks for getting me passed the initial error, I would have pulled out the hairs on my chest trying to figure this one out...I'm already bald from other scripts. :-)

Well done! I did wonder whether it was something like this, but I did not have a good enough knowledge of the script to work it out, so I made some other suggestions Really glad that the problem has been fixed!

Richard